CodeRepos Ubiquitifier

Gist Ubiquitifierが良さそうなアイデアだったので、CodeRepos Ubiquitifierを作ってみました。

nameにスクリプト名(スクリプトのname)、codereposのrevision番号がパラメータで、以下のようなURLに例えばアクセスします。

http://localhost/~dann/ubiquity.cgi?name=cpan&revision=18672

そうすると、subscribe画面が出るので後はインストールするだけです。
上記のURLでインストールされるのは、
http://coderepos.org/share/browser/lang/javascript/ubiquity/cpan.js
のスクリプトです。

http://gist.github.com/8406

#!/usr/bin/perl
use strict;
use warnings;
 
use Readonly;
use Template;
use LWP::UserAgent;
use HTTP::Request;
use CGI;
use CGI::Carp qw(fatalsToBrowser);
use utf8;
use Encode;
use open &#39;:utf8&#39;;
binmode STDIN, ":utf8";
binmode STDOUT, ":utf8";
 
Readonly my $BASEURL => &#39;http://coderepos.org/share/export/&#39;;
Readonly my $UBIQUITY_DIR => &#39;/lang/javascript/ubiquity/&#39;;
Readonly my $EXTENSION => &#39;.js&#39;;
 
our $q;
main();
 
sub main {
    init();
    print_header();
    my $params = parse_parameters();
    validate_parameters($params);
    process_templae($params);
}
 
sub init {
    $q = new CGI;
}
 
sub print_header {
    print $q->header( -charset => "UTF-8" );
}
 
sub validate_parameters {
    my $params = shift;
    check_script_existed( _script_url($params) );
}
 
sub parse_parameters {
    my $params = {};
    $params->{name} = decode( &#39;utf-8&#39;, $q->param(&#39;name&#39;) );
    $params->{revision} = decode( &#39;utf-8&#39;, $q->param(&#39;revision&#39;) );
    $params;
}
 
sub check_script_existed {
    my $url = shift;
    my $request = HTTP::Request->new( GET => $url );
    my $ua = LWP::UserAgent->new;
    my $response = $ua->request($request);
    if ( $response->is_success ) {
        return;
    }
    else {
        die "oooops. this script doesn&#39;t exist on coderepos:" . $url;
    }
}
 
sub process_templae {
    my $opt = shift;
    my $tt = Template->new() || die $Template::ERROR, "\n";
    my $vars = { %{$opt}, url => _script_url($opt), };
    $tt->process( \*DATA, $vars ) || die $tt->error(), "\n";
}
 
sub _script_url {
    my $opt = shift;
    return
          $BASEURL
        . $opt->{revision}
        . $UBIQUITY_DIR
        . $opt->{name}
        . $EXTENSION;
}
 
__END__
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="ja" lang="ja">
  <head>
    <meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
    <title>CodeRepos Ubiquitifier</title>
    <link href="[% url | html %]" name="[% name | html %]" rel="commands" />
  </head>
  <body>
    <h1>
      Install Ubiquity Command: [% name | html %]
    </h1>
    <p>
    The source of this command is
    <a href="[% url | html %]">[% url | html %]</a>
    </p>
  </body>
</html>